ANSYS提供的现成的动画制作功能已经非常丰富，各种计算结果的变形动画、时间历程动画、切片动画、粒子轨迹动画等等，均可通过一个简单的菜单即可完成。即便如此，对于一些特殊的要求来说，尚无法直接实现。对于这种情况，ANSYS提供的“片内存（Segment Memory）”技术就可以用来制作任意的动画。比如，如果我们要做一个旋转几何模型的动画（以便于清楚地看到几何结构），就可以按如下方式实现（先绕屏幕X轴旋转，再绕屏幕Y周旋转）：
/dv3d,anim,2
/seg,dele
/seg,multi,file,0.2
vplot
！
/ang,1,10,xs,1
/replot
/ang,1,10,xs,1
/replot
! ……可类似重复很多次
/ang,1,10,ys,1
/replot
/ang,1,10,ys,1
/replot
! ……也可类似重复很多次
！
/seg,off,file,0.2
/anfile,save,file,avi
/eof
为了更为清晰地展示分析结果，动画效果必不可少。贴出一个动画制作
的命令流文件，供各位兄弟参考。该命令流文件的关键命令：
/NOERASE 通常在显示新的图形时，会清除旧图形，而使用了该命令，可以
在显示新图时，保留旧图，从而使得不同图形同时展现在一张图上。
/UDOC,2,LOGO,OFF 关闭商标命令，有经验的弟兄知道，当要显示等值线图
时，ANSYS的商标是删不掉的，然而用了这个命令，即可
在显示等值线图时也关闭ANSYS商标，注意/UDOC命令的
LOGO选项在ANSYS说明中是没有的。命令中的2是指第二
个窗口。
结果文件：
文件名：
TRANS_ANIMATE.ANS
内容：
－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
!动力分析结果动画制作命令流
!赵昕，2003.4.15
!上海同济大学建筑工程系
FINISH
/TITLE,Transient Dynamic Analysis of Concrete Water Tank Under Seismic Input
! Window1 Settings 窗口1显示时程分析结果
/CONT,1, 9, -0.315, 0.07 !等值云图设置
/UDOC,1,CNTR,RIGHT !等值云图标注位置
/UDOC,1,LOGO,OFF !关闭商标
/UDOC,1,TYPE,OFF !关闭元素标识
/UDOC,1,TYP2,OFF !关闭元素标识
! Window2 Settings 窗口2放置地震动曲线
/WIND,2, -1.0000, 1.6660 , -0.9000 , -0.1000 !窗口2大小设置
/UDOC,2,LOGO,OFF !关闭商标
/UDOC,2,TYPE,OFF !关闭元素标识
/UDOC,2,TYP2,OFF !关闭元素标识
!----------------------------------------
! 进入后处理，定下总时间步和结束时间
! MYSBST = 总时间步
! MYENDT = 结束时间
!----------------------------------------
/POST1
SET,LAST
*GET,MYSBST,ACTIVE,,SET,LSTP
*GET,MYENDT,ACTIVE,,SET,TIME
FINISH
!----------------------------------------
! 进入后处理，决定等值云图的最大、最小值
!----------------------------------------
!/POST1
!/CONTOUR,ALL,AUTO
!PLNSOL,U,X
!取出当前等值云图的参数值
!*GET,_SMIN,COMMON,,D3COM,,REAL,291
!*GET,_SMAX,COMMON,,D3COM,,REAL,292
!*GET,_NUM,GRAPH,1,CONTOUR,NCONT ! 取值数目
!_RNG=(_SMAX-_SMIN) ! 取值范围
!_MIN=_SMIN ! 最小值
!_MAX=_SMAX ! 最大值
!FINISH
!MYSBST=5
*DO, ICOUNT,1,MYSBST,10
/SHOW,PNG
/RGB,INDEX,100,100,100, 0
/RGB,INDEX, 80, 80, 80,13
/RGB,INDEX, 60, 60, 60,14
/RGB,INDEX, 0, 0, 0,15
!----------------------------------------
!单激活窗口1
!----------------------------------------
/WIN,1,OFF
/WIN,2,OFF
/POST1
/WIN,1,ON
!--------------------------------------
!打开子步#ICOUNT并提取时间
!--------------------------------------
SET,,,1,,,,ICOUNT
*GET,MYTIME,ACTIVE,,SET,TIME
!--------------------------------------
!画等值云图
!--------------------------------------
! /CONT,ALL,_NUM,_MIN,,_MAX
PLNSOL,U,X
/NOERASE
FINISH
!----------------------------------------
!单激活窗口2
!----------------------------------------
/WIN,1,OFF
/WIN,2,ON
!---------------------------------------
!在下面窗口画地震动输入曲线
!--------------------------------------
/AXLAB,x,Time
/AXLAB,y,Acceleration(m/s*s)
/XRANG,0,MYENDT
/YRANG,-1,1
!--------------------------------------
!用蓝色线显示整个时程
!--------------------------------------
/COLOR,CURVE,BLUE,1
/GTHK,CURVE,1
/GROPT,DIG2,1
*VPLOT,ELX(1,0),ELX(1,1)
*DIM,MYTEMP,TABLE,ICOUNT,ICOUNT
*VOPER,MYTEMP(1,0),ELX(1,0),ADD
*VOPER,MYTEMP(1,1),ELX(1,1),ADD
/COLOR,CURVE,RED,1
/GTHK,CURVE,2
*VPLOT,MYTEMP(1,0),MYTEMP(1,1)
! *DEL,MYTEMP
/RGB,INDEX, 0, 0, 0, 0
/RGB,INDEX, 60, 60, 60,13
/RGB,INDEX, 80, 80, 80,14
/RGB,INDEX,100,100,100,15
/show,close
/ERASE
*ENDDO
/POST1
/DEVICE,ANIM,AVI
/SEG,DELE
/SEG,MULTI,JOBNAME,0.25
CMSEL,S,BASEE
ALLSEL,BELOW,ELEM
PLETAB,S1_0.001,AVG
*DO,I,1,10
CMSEL,A,JJZC%I%
ALLSEL,BELOW,ELEM
*DO,J,(I-1)*10+1,I*10
PLETAB,S1_%J%,AVG
*ENDDO
*ENDDO
/SEG,OFF,JOBNAME,0.25
/SEG,PC